TODAY

Description

Use this function to get the numeric date value of the current day.

Syntax

TODAY()

Inputs

This function has no user-supplied inputs. It does require that the Document, Spreadsheet or Presentation have the timezone property set. Refer to the Notes section at the bottom of this page for information on setting this property.

Examples

Note: All examples are set using the US date format.

Sample data

	A
1	2/20/2023
2	8/1/2026
3	8/25/2026
4	12/1/2026

Sample formulas

Note: The displayed value is determined by the cell format. If the cell format is "Automatic" or "Number", it will display an integer. If the cell format is "Date", by default it will display a date based on your locale. If you want another format, click the value format pulldown in the Edit menu and select "More Formatting Options". For additional information, see the Workiva Support page Format values and numbers.

Use case	Formula	Explanation and Result
Return the current date.	`=TODAY()`	If the current date is 8/25/2026, the result is: 46259. To view this as a date, change the cell format to "Date". Changing the cell format to "Date" changes the displayed result to: 8/25/2026
Return the date 7 days forward from the current date.	`=TODAY()+7`	If the current date is 8/25/2026, the result is 46266. (46259+7). Changing the cell format to "Date" changes the displayed result to: 9/1/2026.
Return the number of days between the current date and a supplied date.	`=A1-TODAY()`	If the current date is 8/25/2026, the result is -1282, as the supplied date in cell A1 (see sample data above) is 2/20/2023.
Return the number of days between the current date and 1/1/2035.	`=DATEVALUE("1/1/2035")-TODAY()`	If the current date is 8/25/2026, the result is: 3051.^*
Return the number of the current day of the month.	`=DAY(TODAY())`	If the current date is 8/25/2026, the result is: 25.^*
Return the current month of the year as a number.	`=MONTH(TODAY())`	If the current date is 8/25/2026, the result is: 8.^*
Return the day of the week for the current day.	`=WEEKDAY(TODAY())`	If the current date is 8/25/2026, the result is: 3.^*
Return the current month of the year as a word.	`=TEXT(TODAY(), "mmmm")`	If the current date is 8/25/2026, the result is: August. This formula works as follows: For the full name (e.g., August), use: `=TEXT(TODAY(), "mmmm")` For the three-letter abbreviation (Aug), use: `=TEXT(TODAY(), "mmm")`.
Identify the current quarter.	`="Q"&ROUNDUP(MONTH(TODAY())/3,0)`	If the current date is 8/25/2026, the result is: Q3. This formula works as follows: `MONTH(TODAY())` determines today's month as a number (1–12). Today is August, so this returns `8`. This value is then divided by 3: `8/3 = 2.667`. `ROUNDUP(…, 0)` rounds that up to the next whole number: `3`

^*The cell must be formatted as "Automatic" or "Number" for the result to display as a number.

Notes

TODAY uses the timezone property set in the Document, Presentation, or Spreadsheet — not the time zone of the user viewing it. So while the value is the same for all users, it may not match the date where the viewer is or the timezone set in the user's profile. For example, if the document's time zone is set to Honolulu, a user in Paris might see the previous day's date.
For a new Document, Presentation, or Spreadsheet, the timezone property is set from your user profile. If timezone is not set in your user profile, any new documents you create will not have a timezone value, and formulas using TODAY will not work. To avoid this, set the timezone in your user profile before you create documents.
See the Workiva Support page Edit your profile for how to do this.
For an existing Document, Presentation, or Spreadsheet, the timezone property is not set automatically; you will have to set the timezone property manually for formulas using TODAY to work.
For information on setting the document-level timezone, see "Change general settings" on the Document and section properties Support page.
You can change the timezone property of a Document, Presentation, or Spreadsheet at any time, for example to match a specific time zone needed for your calculations.
Your locale setting determines the default date format (MM/DD/YYYY or DD/MM/YYYY).
Refer to the Workiva Support page Format values and numbers for detailed information on how cell format settings can change how a date is displayed.
TODAY recalculates only when:
- A Document, Presentation, or Spreadsheet containing the function is opened.
- The browser window containing the Document, Presentation, or Spreadsheet is refreshed.
- A cell referenced by the formula changes.

Caution: If your document has a lot of formulas that are dependent on TODAY, such a recalculation could take a long time.

Related functions

Workiva Support Center