MOD

Descrição

Use essa função para retornar o restante de dois números após a divisão. Apoiado em cadeias.

O resultado de MOD tem o mesmo sinal do divisor. Se divisor for positivo, o resultado de MOD será positivo; se divisor for negativo, o resultado de MOD será negativo.

Sintaxe

MOD(número, divisor)

Entradas

Essa função tem os seguintes argumentos:

Nome	Necessário	Descrição	Entrada válida
`número`	Sim	O número a ser dividido.	Uma referência de célula, um número ou uma fórmula que resulta em um desses itens.
`divisor`	Sim	O valor pelo qual você dividirá o número.	Uma referência de célula, um número ou uma fórmula que resulta em um destes.

Exemplos

Dados de amostra

Tabela 1

	A	B	C	D	E
1	Data	Cookies vendidos	Cookies por pacote	Excedente	Pacotes	Oculto
2	12/1/2024	45	4	1	12	FALSE
3	12/2/2024	34	4	2	9	FALSE
4	12/3/2024	35	6	5	6	TRUE
5	12/4/2024	40	4	0	10	FALSE
6	12/5/2024	24	4	0	6	FALSE
7	12/6/2024	34	4	2	9	TRUE
8	12/7/2024	36	6	0	6	FALSE
9	12/8/2024	41	4	1	11	FALSE
10	12/9/2024	25	6	1	5	TRUE
11	12/10/2024	37	4	1	10	FALSE
12	12/11/2024	33	4	1	9	FALSE
13	12/12/2024	15	4	3	4	TRUE
14	12/13/2024	23	4	3	6	FALSE
15	12/14/2024	43	4	3	11	FALSE

Tabela 2

	A	B.	C	D
1	Data	Horas trabalhadas	Horas	Minutos
2	12/2/2024	7.5	7	30
3	12/3/2024	6.75	6	45

Tabela 3

	A	B
1	Data e hora	Tempo padrão
2	12/2/24 10:40 AM	10:40 AM
3	12/4/24 10:14 AM	10:14:10 AM
4	12/5/24 10:37 AM	10:37:20 AM
5	12/6/24 9:50 AM	9:50:00 AM

Fórmulas de amostra

Caso de uso	Fórmula	Explicação e resultado
Calcule o restante após uma divisão (D2), o resultado inteiro (E2) e o número total de pacotes necessários (F2).	Em D2: `=MOD(B2,C2)` Em E2: `=INT(B2/C2)` Em F2: `=ROUNDUP(B2/C2, 0)`	Usando os dados da Tabela 1, essa fórmula funciona da seguinte maneira: `=MOD(B2,C2)`: (45, 4) Retorna o resto 1. (Resultado em D2). `=INT` `(B2/C2)`: (45/4) = 11.25. Retorna a parte inteira, 11. (Resultado em E2) `=ROUNDUP(B2/C2, 0)`: (45/4) = 11.25. Você arredonda para o próximo inteiro, 12. (Resultado em F2).
Você divide um valor de hora baseado em decimais em horas e minutos.	Em C2: `=INT(B2)` Em D2: `=MOD(B2,1)*60`	Usando os dados da Tabela 2, essa fórmula funciona da seguinte maneira: `=INT(B2)`: Como B2 = 7,5, isso retorna a parte inteira, 7. (Resultado em C2). `=MOD(B2,1)60`: Como B2 = 7,5, `MOD(7,5, 1)` retorna o resto decimal, 0,5. 0,560 = 30. (Resultado em D2).
Extraia o tempo (como texto) de uma célula que contenha data e hora.	`=TEXT(MOD(A2,1), "h:mm:ss AM/PM")`	Usando os dados da Tabela 3, essa fórmula funciona da seguinte maneira: `MOD(A2,1)`: Divide o valor de data/hora em A2 por 1 e retorna o restante. A parte inteira de um valor de data/hora é a data; a parte decimal é o tempo. Isso isola o tempo (0,4444...). `TEXT(…)`: Formata o decimal resultante (0,4444...) em uma cadeia de tempo legível com base no formato "h:mm:ss AM/PM". Para esse conjunto de dados, a fórmula retorna 10:40:00 AM.
Localize a última sexta-feira de um determinado mês.	`=TEXT(EOMONTH(A2,0)-MOD(EOMONTH(A2,0)-6,7), "dd/mm/yyyyy")`	Usando os dados da Tabela 1, essa fórmula funciona da seguinte maneira: `EOMONTH(A2, 0)`: Localiza o último dia do mês para a data em A2 (1/12/2024), que é 31/12/2024. `EOMONTH(A2,0)-6`: Subtrai 6 dias (para localizar a sexta-feira daquela semana, supondo que 1=domingo...6=sexta-feira). `MOD(..., 7)`: Calcula o resto quando dividido por 7, localizando o deslocamento do dia da semana. `EOMONTH(…) - MOD(…)`: Subtrai o deslocamento do último dia do mês para localizar a data da última sexta-feira. `TEXT(…)`: formata o número de série de data resultante como "dd/mm/aaaa". Para esse conjunto de dados, a fórmula retorna 27/12/2024.

Notas

MOD retorna o restante após a divisão. Por exemplo, MOD(3,2) retorna 1, porque 2 entra em 3 uma vez, com um resto de 1.
Os curingas não funcionam com essa função.

Dicas:

Evite erros "#DIV/0": Use IF para verificar se há um divisor zero: =IF(B1=0, "Error", MOD(A1, B1)).

Funções relacionadas

Suporte

Comunidade

Centro de suporte da Workiva

MOD